one love, infinite variety (contextfree.2) «
   

one love, infinite variety
is another CFDG-based experiment,
in which I trace the path of an
afternoon spent riffing
on one single shape
as the semi-atomic
fundamental unit:

    

This shape is equal parts
heart, leaf and eye;
a useful choice as the
shape is permutated
myriad ways.

 

The first tests
were recursive calls
of the main shape
augmented with simple
translation and/or rotation
instructions.

 

» next experiment

Those first shapes sparked an idea to rotate the original image into a flower containing recursive copies of itself within.
And then I spiraled the result for good measure.
 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_FLOWER_SPIRAL
// info: mandalabrot.net / kiddphunk.com / 2005

startshape FLOWER_SPIRAL

rule FLOWER_SPIRAL {
	FLOWER_COMPLEX {}
	FLOWER_SPIRAL { s .94 x 20 r 30 }
}

rule FLOWER_COMPLEX {
	FLOWER {}
	FLOWER { s .32 b 1 }
	FLOWER_COMPLEX  { s .12 }
}

rule FLOWER  {
	FLOWER__BOTH {}
	FLOWER__BOTH { r 30 }
	FLOWER__BOTH { r -30 }
	FLOWER__BOTH { r 60 }
	FLOWER__BOTH { r -60 }
	FLOWER__BOTH { r 90 }
	FLOWER__BOTH { r -90 }
	FLOWER__BOTH { r 120 }
	FLOWER__BOTH { r -120 }
	FLOWER__BOTH { r 150 }
	FLOWER__BOTH { r -150 }
	FLOWER__BOTH { r -180 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6  s .4 }
}

rule FLOWER__RIGHT {
	CIRCLE { } 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE { } 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
The previous flower inspired recursive and reflexive
additions to itself, resulting in a
complex fractal doily.
 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_FLOWER_DOILY
// info: mandalabrot.net / kiddphunk.com / 2005

startshape FLOWER_DOILY

rule FLOWER_DOILY {
	FLOWER_COMPLEX {}
	FLOWER_COMPLEX { r 45 }
}

rule FLOWER_COMPLEX {
	FLOWER {}
	FLOWER_COMPLEX { s .3 x 10.4 }
	FLOWER_COMPLEX { s .3 x 10.4 }
	FLOWER_COMPLEX { s .3 x -10.4 }
	FLOWER_COMPLEX { s .3 y -10.4 }
	FLOWER_COMPLEX { s .3 y 10.4 }
	FLOWER { s .5 b 1 }
}

rule FLOWER  {
	FLOWER__BOTH {}
	FLOWER__BOTH { r 30 }
	FLOWER__BOTH { r 60 }
	FLOWER__BOTH { r 90 }
	FLOWER__BOTH { r 120 }
	FLOWER__BOTH { r 150 }
	FLOWER__BOTH { r -30 }
	FLOWER__BOTH { r -60 }
	FLOWER__BOTH { r -90 }
	FLOWER__BOTH { r -120 }
	FLOWER__BOTH { r -150 }
	FLOWER__BOTH { r -180 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6  s .4 }
	FLOWER__BOTH { r -120 s .4 }
	FLOWER__BOTH { r 120 s .4 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
I then decided to return to the original form
to see what else the shape would reveal.
First up: a feathered pinwheel...
 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_FEATHER_SPIRAL
// info: mandalabrot.net / kiddphunk.com / 2005

startshape FEATHER_SPIRAL

rule FEATHER_SPIRAL {
	FEATHER_SPIRAL__TIPTOP {  }
	FEATHER_SPIRAL__TIPTOP { r 90 }
	FEATHER_SPIRAL__TIPTOP { r -90 }
	FEATHER_SPIRAL__TIPTOP { r 180 }
}

rule FEATHER_SPIRAL__TIPTOP {
	FEATHER_SPIRAL__TOP {}
	FEATHER_SPIRAL__TIPTOP { s .9 r -10 }
}

rule FEATHER_SPIRAL__TOP {
	FEATHER_SPIRAL__SHAPE {}
	FEATHER_SPIRAL__TOP { s .95 x 20 r 10 }
}

rule FEATHER_SPIRAL__SHAPE {
	FEATHER_SPIRAL__SHAPE2 {}
	FEATHER_SPIRAL__SHAPE { s .1 }
}

rule FEATHER_SPIRAL__SHAPE2 {
	FLOWER__BOTH {}
	FEATHER_SPIRAL__SHAPE2 { r 4 s .8 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6 s .3 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { rotate 2 size 0.982 y .9909067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { rotate -2 size 0.982 y .9909067 }
}
« top of experiment
...and then a mandala of sorts.
 

 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_EYE_MANDALA
// info: mandalabrot.net / kiddphunk.com / 2005

startshape EYE_MANDALA

rule EYE_MANDALA {
	EYE_MANDALA__SHAPER {}
}

rule EYE_MANDALA__SHAPER {
	EYE_MANDALA__SHAPE {}
	EYE_MANDALA__SHAPER { r -10 }
}

rule EYE_MANDALA__SHAPE {
	EYE_MANDALA__GROW { x 44 }
	EYE_MANDALA__GROW2 {}
}

rule EYE_MANDALA__GROW {
	FLOWER__BOTH {}
	EYE_MANDALA__GROW { r 10 s .8 y 10 }
}

rule EYE_MANDALA__GROW2 {
	FLOWER__BOTH {}
	EYE_MANDALA__GROW2 { r -10 s .8 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
An infinite field of all-seeing eyes guides the traveler.
This manifestation felt similar to some elements
of Alex Grey's inspiring painting*...
 

« prev | next »

 

« back | *The image instantly reminded me of
this Alex Grey piece:

 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_EYE_MANDALA
// info: mandalabrot.net / kiddphunk.com / 2005

startshape EYE_MANDALA

rule EYE_MANDALA {
	EYE_MANDALA__TOPSHAPER {}
	EYE_MANDALA {r 10}
}

rule EYE_MANDALA__TOPSHAPER {
	EYE_MANDALA__SHAPER {}
}

rule EYE_MANDALA__SHAPER {
	EYE_MANDALA__SHAPE {}
	EYE_MANDALA__SHAPER { s .9 r -2 }
}

rule EYE_MANDALA__SHAPE {
	EYE_MANDALA__GROW { x 50 }
}

rule EYE_MANDALA__GROW {
	FLOWER__BOTH {}
	EYE_MANDALA__GROW { r 10 s .8 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
A nautilus shell.
 

 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_NAUTILUS_SHELL
// info: mandalabrot.net / kiddphunk.com / 2005

startshape NAUTILUS_SHELL

rule NAUTILUS_SHELL {
	NAUTILUS_SHELL__SHAPE {}
	NAUTILUS_SHELL { s .94 x 2 r 10 }
}

rule NAUTILUS_SHELL__SHAPE {
	NAUTILUS_SHELL__SHAPE2 {}
	NAUTILUS_SHELL__SHAPE { s .12 }
}

rule NAUTILUS_SHELL__SHAPE2 {
	FLOWER__BOTH {}
	NAUTILUS_SHELL__SHAPE2 { r 10 s .9 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6 s .2 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
The great wave.
 

 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_EYE_WAVES
// info: mandalabrot.net / kiddphunk.com / 2005
//
// i didn't save the original code for this one
// so i have (somewhat) recreated the code:

startshape EYE_WAVES

rule EYE_WAVES {
	EYE_WAVES__SHAPE {}
}

rule EYE_WAVES__SHAPE {
	FLOWER__BOTH {}
	EYE_WAVES__SHAPE { r 30 s .81 x 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	EYE_WAVES { s .6 r 30 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
Infinite field of eyes. Another Alex Grey-inspired image.
 

 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_EYE_FIELDS
// info: mandalabrot.net / kiddphunk.com / 2005

startshape EYE_FIELDS

rule EYE_FIELDS {
	EYE_FIELDS__SHAPE {}
	EYE_FIELDS { s .94 x 20 r 30 }
}

rule EYE_FIELDS__SHAPE {
	FLOWER__BOTH {}
	EYE_FIELDS__SHAPE { r 10 s .8 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6 s .2 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
A simple variation.
 

 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_EYE_FIELDS
// info: mandalabrot.net / kiddphunk.com / 2005

startshape EYE_FIELDS

rule EYE_FIELDS {
	EYE_FIELDS__SHAPE {}
	EYE_FIELDS { s .94 x 20 r 30 }
}

rule EYE_FIELDS__SHAPE {
	FLOWER__BOTH {}
	EYE_FIELDS__SHAPE { r 10 s .9 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6 s .2 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment
One final variation ends a sucessful round of
{spontaneous, iterative, randomized} design magick.
I have only scratched the surface of the ideas in my head.
 

« prev | next » 

// namespace: NET_MANDALABROT
// name: NET_MANDALABROT_EYE_FIELDS
// info: mandalabrot.net / kiddphunk.com / 2005

startshape EYE_FIELDS

rule EYE_FIELDS {
	EYE_FIELDS__SHAPE {}
	EYE_FIELDS { s .94 x 20 r 30 }
}

rule EYE_FIELDS__SHAPE {
	FLOWER__BOTH {}
	EYE_FIELDS__SHAPE { r 10 s .99 y 10 }
}

rule FLOWER__BOTH {
	FLOWER__LEFT { r 44.3 }
	FLOWER__RIGHT { r -44.3 }
	FLOWER__BOTH { y 6 s .2 }
}

rule FLOWER__RIGHT {
	CIRCLE {} 
	FLOWER__RIGHT { r 1 s 0.982  y .209067 }
}

rule FLOWER__LEFT {
	CIRCLE {} 
	FLOWER__LEFT { r -1 s 0.982 y .209067 }
}
« top of experiment